Oracle 21c

By using db<>fiddle, you agree to license everything you submit by Creative Commons CC0.
CREATE TYPE number_list IS TABLE OF NUMBER;
CREATE TABLE person (id, name) AS
SELECT 1, 'Alice' FROM DUAL UNION ALL
SELECT 2, 'Beryl' FROM DUAL UNION ALL
SELECT 3, 'Carol' FROM DUAL UNION ALL
SELECT 4, 'Debra' FROM DUAL;
4 rows affected

CREATE PACKAGE your_package IS
  TYPE Ids_t_a is table of Number index by binary_integer;

  FUNCTION map_ids(
    Ids     in  Ids_t_a
  ) RETURN number_list PIPELINED;

  PROCEDURE GetData(
    Ids     in  Ids_t_a,
    results out sys_refcursor
  );
END;
/
CREATE PACKAGE BODY your_package IS
  FUNCTION map_ids(
    Ids     in  Ids_t_a
  ) RETURN number_list PIPELINED
  IS
    v_idx BINARY_INTEGER;
  BEGIN
    IF ids IS NULL THEN
      RETURN;
    END IF;
    v_idx := ids.FIRST;
    WHILE v_idx IS NOT NULL LOOP
      PIPE ROW(ids(v_idx));
      v_idx := ids.NEXT(v_idx);
    END LOOP;
  END;

  PROCEDURE GetData(
    Ids     in  Ids_t_a,
    results out sys_refcursor
  )
  IS
  BEGIN
    Open Results for
      SELECT Id, Name
      FROM   Person
      WHERE  Id MEMBER OF map_ids(ids);
  END;
END;
/
SELECT * FROM USER_ERRORS;
DECLARE
  v_cur  SYS_REFCURSOR;
  v_ids  YOUR_PACKAGE.IDS_T_A;
  v_id   PERSON.ID%TYPE;
  v_name PERSON.NAME%TYPE;
BEGIN
  v_ids(1) := 3;
  v_ids(3) := 1;
  v_ids(42) := 7;
  YOUR_PACKAGE.GetData(v_ids, v_cur);
  LOOP
    FETCH v_cur INTO v_id, v_name;
    EXIT WHEN v_cur%NOTFOUND;
    DBMS_OUTPUT.PUT_LINE(v_id || ': ' || v_name);
  END LOOP;
END;
/
1 rows affected

dbms_output:
1: Alice
3: Carol