SQL Server 2022

By using db<>fiddle, you agree to license everything you submit by Creative Commons CC0.
CREATE FUNCTION KnuthHashUnicode1(@String NVARCHAR(MAX))
RETURNS VARCHAR(20)
AS
BEGIN
    -- Adaptation of C# hash algorithm posted at https://stackoverflow.com/a/9545731
    -- WARNING: This hash is **not** crypographically secure.

    -- NOTE: This algorithm depends on the fact that the @Multiplier value is such
    -- that @Multiplier * @TwoPower64 does not exceed the NUMERIC(38,0) capacity.
  
    -- Key values
    DECLARE @Seed       NUMERIC(38,0) =  3074457345618258791
    DECLARE @Multiplier NUMERIC(38,0) =  3074457345618258799
    DECLARE @TwoPower64 NUMERIC(38,0) = 18446744073709551616 -- 2^64
    
    -- Initialize
    DECLARE @Hash NUMERIC(38,0) = @Seed
    
    -- Get the true length of string, including possible trailing spaces
    DECLARE @Len INT = DATALENGTH(@String) / 2
    
    DECLARE @Pos INT = 0
    WHILE @Pos < @Len
    BEGIN
        SET @Pos += 1
        DECLARE @Value BIGINT = UNICODE(SUBSTRING(@String, @Pos, 1))
        
        SET @Hash = (@Hash + @Value) % @TwoPower64
        SET @Hash = (@Hash * @Multiplier) % @TwoPower64
    END
    
    -- Format and return as string
    RETURN CAST(@Hash AS VARCHAR(20))
END
CREATE FUNCTION KnuthHashUnicode2(@String NVARCHAR(MAX))
RETURNS VARCHAR(20)
AS
BEGIN
    -- Adaptation of C# hash algorithm posted at https://stackoverflow.com/a/9545731
    -- WARNING: This hash is **not** crypographically secure.

    -- Key values are conveniently < 2^63, so they fit in a signed BIGINT.
    DECLARE @Seed BIGINT = 3074457345618258791
    DECLARE @Mult BIGINT = 3074457345618258799
    
    -- We will be doing arithmatic in three slices: 2 x 24-bit and 1 x 16-bit
    DECLARE @Mask24 BIGINT = 0xFFFFFF -- 24 bits (Lo and Md parts)
    DECLARE @Mask16 BIGINT = 0xFFFF   -- 16 bits (Hi part)
    
    DECLARE @SeedLo BIGINT = @Seed & @Mask24
    DECLARE @SeedMd BIGINT = (@Seed >> 24) & @Mask24
    DECLARE @SeedHi BIGINT = @Seed >> 48
    
    DECLARE @MultLo BIGINT = @Mult & @Mask24
    DECLARE @MultMd BIGINT = (@Mult >> 24) & @Mask24
    DECLARE @MultHi BIGINT = @Mult >> 48
    
    -- Initialize
    DECLARE @HashHi BIGINT = @SeedHi
    DECLARE @HashMd BIGINT = @SeedMd
    DECLARE @HashLo BIGINT = @SeedLo
    
    -- Get the true length of string, including possible trailing spaces
    DECLARE @Len INT = DATALENGTH(@String) / 2
    
    DECLARE @Pos INT = 0
    WHILE @Pos < @Len
    BEGIN
        SET @Pos += 1
        DECLARE @Value BIGINT = UNICODE(SUBSTRING(@String, @Pos, 1))
        
        -- Add with carry
        DECLARE @SumLo BIGINT = @HashLo + @Value
        DECLARE @SumMd BIGINT = @HashMd + (@SumLo >> 24)
        DECLARE @SumHi BIGINT = @HashHi + (@SumMd >> 24)
        SET @HashLo = @SumLo & @Mask24
        SET @HashMd = @SumMd & @Mask24
        SET @HashHi = @SumHi & @Mask16
        
        -- Cross-multiply with carry
        -- (No need to calculate product components > 64 bits)
        DECLARE @ProdLo BIGINT = (@HashLo * @MultLo)
        DECLARE @ProdMd BIGINT = (@HashMd * @MultLo)
                               + (@HashLo * @MultMd)
                               + (@ProdLo >> 24)
        DECLARE @ProdHi BIGINT = (@HashHi * @MultLo)
                               + (@HashMd * @MultMd)
                               + (@HashLo * @MultHi)
                               + (@ProdMd >> 24)
        SET @HashLo = @ProdLo & @Mask24
        SET @HashMd = @ProdMd & @Mask24
        SET @HashHi = @ProdHi & @Mask16
    END
    
    -- Combine slices
    DECLARE @Result BIGINT = (@HashHi << 48) | (@HashMd << 24) | (@HashLo)

    -- Convert to numeric and adjust for negative
    DECLARE @ResultNum NUMERIC(20,0) = CAST(@Result AS NUMERIC(20,0)) 
    IF @ResultNum < 0 SET @ResultNum += 18446744073709551616 -- 2^64

    -- Format and return as string
    RETURN CAST(@ResultNum AS VARCHAR(20))
END
CREATE TABLE TestData (
    Id INT IDENTITY(1,1),
    String NVARCHAR(MAX)
)
INSERT TestData
VALUES
    (''),                                 -- Empty string should return seed value
    (' '),                                -- Single space
    ('Hello World'),
    ('Hello World '),                     -- Trailing space is significant
    (N'αβγδ абвг 你好世界 ∫∬∭∮ 🅐🅑🅒🅓'), -- 16-bit characters and surrogate pairs
    ('The quick brown fox jumps over the lazy dog.')

SELECT
    String,
    dbo.KnuthHashUnicode1(String) AS Result1,
    dbo.KnuthHashUnicode2(String) AS Result2
FROM TestData
ORDER BY Id


String
Result1
Result2



3074457345618258791
3074457345618258791

 
16397105843297422473
16397105843297422473

Hello World
5485109609273439365
5485109609273439365

Hello World
10073154357816199819
10073154357816199819

αβγδ абвг 你好世界 ∫∬∭∮ 🅐🅑🅒🅓
5168594500780613104
5168594500780613104

The quick brown fox jumps over the lazy dog.
5118964073116902044
5118964073116902044
String	Result1	Result2
	3074457345618258791	3074457345618258791
	16397105843297422473	16397105843297422473
Hello World	5485109609273439365	5485109609273439365
Hello World	10073154357816199819	10073154357816199819
αβγδ абвг 你好世界 ∫∬∭∮ 🅐🅑🅒🅓	5168594500780613104	5168594500780613104
The quick brown fox jumps over the lazy dog.	5118964073116902044	5118964073116902044