SQL Server 2019

By using db<>fiddle, you agree to license everything you submit by Creative Commons CC0.
CREATE TABLE dbo.YourTable (Department varchar(10),
                            Driver varchar(10));
INSERT INTO dbo.YourTable
VALUES('Store','Driver-1'),
      ('Store','Driver-2'),
      ('Store','Driver-3');
3 rows affected

DECLARE @Dept varchar(10) = 'Store';

DECLARE @SQL nvarchar(MAX),
        @CRLF nchar(2) = NCHAR(13) + NCHAR(10);
DECLARE @Delimiter nvarchar(30) = N',' + @CRLF + N'       ';

SELECT @SQL = N'SELECT ' + STRING_AGG(N'Department AS ' + QUOTENAME(Driver),@Delimiter) WITHIN GROUP (ORDER BY Driver ASC) + @CRLF +
              N'FROM dbo.YourTable YT' + @CRLF +
              N'WHERE Department = @Dept' + @CRLF +
              N'GROUP BY Department;'
FROM dbo.YourTable YT
WHERE Department = @Dept;

PRINT @SQL; --Your best friend
EXEC sys.sp_executesql @SQL, N'@Dept varchar(10)', @Dept;


Driver-1
Driver-2
Driver-3


Store
Store
Store


SELECT Department AS [Driver-1],
       Department AS [Driver-2],
       Department AS [Driver-3]
FROM dbo.YourTable YT
WHERE Department = @Dept
GROUP BY Department;


DROP TABLE dbo.YourTable;