Oracle 18c

By using db<>fiddle, you agree to license everything you submit by Creative Commons CC0.
create table tableA (
  empno integer,
  expcode varchar2(4),
  expyears integer );
create type empno_t as table of integer;
create or replace trigger check_exp
  for insert or update on tableA
  compound trigger
  
  l_empnos empno_t := new empno_t();
  
  after each row
  is
  begin
    l_empnos.extend;
    l_empnos( l_empnos.count ) := :new.empno;
  end after each row;
  
  after statement
  is
    l_invalid_empnos integer;
  begin
    select count(*)
      into l_invalid_empnos
      from tableA expcode1
     where expcode1.expcode = 'EXP1'
       and expcode1.empno MEMBER OF l_empnos
       and exists( select 1
                     from tableA expcode4
                    where expcode4.expcode = 'EXP4'
                      and expcode4.empno = expcode1.empno
                      and expcode4.expyears < expcode1.expyears );
                      
    if( l_invalid_empnos > 0 )
    then
      raise_application_error( -20001, 'EXP4 expyears > EXP1 expyears ');
    end if;
  end after statement;
end;
/
insert into tableA values( 1, 'EXP1', 4 );
1 rows affected

insert into tableA values( 1, 'EXP4', 5 );
1 rows affected

insert into tableA values( 2, 'EXP1', 4 );
1 rows affected

insert into tableA values( 2, 'EXP4', 3 );
ORA-20001: EXP4 expyears > EXP1 expyears
ORA-06512: at "FIDDLE_PUXZEYRENWMZFWVGZJON.CHECK_EXP", line 29
ORA-04088: error during execution of trigger 'FIDDLE_PUXZEYRENWMZFWVGZJON.CHECK_EXP'

insert into tableA values( 3, 'EXP1', 4 );
1 rows affected

insert into tableA values( 3, 'EXP4', 4 );
1 rows affected