Oracle 18c

By using db<>fiddle, you agree to license everything you submit by Creative Commons CC0.
-- made up; not shown in question
CREATE OR REPLACE FUNCTION 
GET_REF_CUR
    (
    p_stmt IN VARCHAR2
    )
RETURN sys_refcursor
IS
    l_rc sys_refcursor;
BEGIN
    open l_rc for p_stmt;
    return l_rc;
END;
/
CREATE OR REPLACE PROCEDURE
GET_REF_HEAD_AND_VAL
    (
    p_cursor IN OUT SYS_REFCURSOR,
    p_col OUT SYS.odcivarchar2list,
    p_val OUT SYS.odcivarchar2list
    )
IS

    l_cursor_id     INTEGER;
    l_col_cnt       INTEGER;
    l_tab_rec       DBMS_SQL.DESC_TAB3;
    l_value         VARCHAR2(250 byte);

BEGIN

    l_cursor_id := DBMS_SQL.TO_CURSOR_NUMBER(p_cursor); 
    DBMS_SQL.DESCRIBE_COLUMNS3(l_cursor_id, l_col_cnt, l_tab_rec);

    /* COLUMN HEADERS */
    p_col := SYS.odcivarchar2list();
    FOR r IN 1..l_col_cnt
    LOOP

        p_col.extend;
        p_col(p_col.count) := l_tab_rec(r).col_name;
        DBMS_SQL.DEFINE_COLUMN(l_cursor_id, r, l_value, 250);

    END LOOP;

    /* COLUMN VALUES */
    p_val := SYS.odcivarchar2list();
    LOOP 
        IF DBMS_SQL.FETCH_ROWS(l_cursor_id) = 0 THEN 
            EXIT; 
        END IF;
    
        FOR i IN 1 .. l_col_cnt
        LOOP
    
            p_val.extend;
            DBMS_SQL.COLUMN_VALUE(l_cursor_id, i, l_value);        
            --DBMS_OUTPUT.PUT_LINE(l_dum_val);
            p_val(p_val.count) := l_value;
    
        END LOOP;
    END LOOP;  

    DBMS_SQL.CLOSE_CURSOR(l_cursor_id);

END;
/
DECLARE

l_sql_stmt VARCHAR(10000) :=
q'!
    SELECT
        SYS_CONTEXT('USERENV','OS_USER') AS OS_USER ,
        SYS_CONTEXT('USERENV','SESSION_USER') AS SESSION_USER,
        SYS_CONTEXT('USERENV','ISDBA') AS ISDBA,
        SYS_CONTEXT('USERENV','SID') AS SID,
        SYS_CONTEXT('USERENV','CURRENT_SQL') AS CURRENT_SQL,
        SYS_CONTEXT('USERENV','DB_NAME') AS DB_NAME,
        SYS_CONTEXT('USERENV','HOST') AS HOST,
        SYS_CONTEXT('USERENV','IP_ADDRESS') AS IP_ADDRESS,
        SYS_CONTEXT('USERENV','SERVICE_NAME') AS SERVICE_NAME
    FROM
        DUAL
!';

    l_val SYS.odcivarchar2list;
    l_col SYS.odcivarchar2list;
    l_cursor        SYS_REFCURSOR;

BEGIN

    l_cursor := GET_REF_CUR(l_sql_stmt);

    IF NOT l_cursor%ISOPEN
    THEN
        RETURN;
    END IF;

    GET_REF_HEAD_AND_VAL(l_cursor, l_col, l_val);

    FOR i IN 1 .. l_col.COUNT
    LOOP
        DBMS_OUTPUT.PUT_LINE(l_col(i));
    END LOOP;

    DBMS_OUTPUT.PUT_LINE('-----');

    /* Values fetch fails */
    FOR i IN 1 .. l_val.COUNT
    LOOP
        DBMS_OUTPUT.PUT_LINE(l_val(i));
    END LOOP;

END;
/
1 rows affected

dbms_output:
OS_USER
SESSION_USER
ISDBA
SID
CURRENT_SQL
DB_NAME
HOST
IP_ADDRESS
SERVICE_NAME
-----
apache
FIDDLE_LDQHLWKUWHWONQKFBVLM
FALSE
81

XEPDB1
localhost.localdomain
127.0.0.1
xepdb1