SQL Server 2017

By using db<>fiddle, you agree to license everything you submit by Creative Commons CC0.

--create demo schema
create table Table1 (col1 int, col2 int)
create table Table2 (col1 int, col3 int)
insert Table1 (col1, col2) values (11, 12)
insert Table2 (col1, col3) values (21, 22)

--actual code to run this

declare @tablesOfInterest table(tableName sysname, sql nvarchar(max))
declare @allColumns table(columnName sysname)
declare @sql nvarchar(max)

insert @tablesOfInterest(tableName) values ('table1'), ('table2')

insert @allColumns (columnName)
select distinct c.name
from sys.columns c 
where c.object_id in
(
    select object_id(tableName)
    from @tablesOfInterest
)

update t
set sql = 'select ' + columnSql + ' from ' + quotename(tableName)
from @tablesOfInterest t
cross apply
(
    select string_agg(coalesce(quotename(c.Name), 'null') + ' ' + quotename(ac.columnName), ', ') within group (order by ac.columnName)
    from @allColumns ac
    left outer join sys.columns c
    on c.object_id = object_id(t.tableName)
    and c.Name = ac.columnName
) x(columnSql)

select @sql = string_agg(sql, ' union all ')
from @tablesOfInterest

print @sql

exec (@sql)

col1	col2	col3
11	12	null
21	null	22

select [col1] [col1], [col2] [col2], null [col3] from [table1] union all select [col1] [col1], null [col2], [col3] [col3] from [table2]