Oracle 18c

By using db<>fiddle, you agree to license everything you submit by Creative Commons CC0.
--Example of creating and reading an ANYDATASET value.
create table book (
    book_id number (3) NOT NULL,
    book_name    SYS.ANYDATASET NOT NULL,
    student_student_id number(5) NOT NULL);
--Add one row with multiple values.
declare
	v_anytype    anytype;
	v_anydataset anydataset;
begin
	anydataset.BeginCreate(typecode => dbms_types.typecode_varchar2, rtype => v_anytype, aset => v_anydataset);

	v_anydataset.addInstance;
	v_anydataset.setVarchar2('Harry Potter and the Philosopher''s Stone');

	v_anydataset.addInstance;
	v_anydataset.setVarchar2('Harry Potter and the Sorcerer''s Stone');

	anydataset.EndCreate(v_anydataset);

	insert into book (book_id, book_name, student_student_id) values ('768', v_anydataset, '58765');
	commit;
end;
/
1 rows affected

--Display all of the book names.
declare
	v_anydataset anydataset;
	v_type pls_integer;
	v_string varchar2(4000);
begin
	--Loop through the rows.
	for anydatasets in
	(
		select book_name
		from book
		order by book_id
	) loop
		--Get the anydataset.
		v_anydataset := anydatasets.book_name;
		v_anydataset.piecewise;

		--Loop through all the elements in the anydataset.
		for i in 1 .. v_anydataset.getCount loop
			v_type := v_anydataset.getInstance;
			v_type := v_anydataset.getVarchar2(v_string);
			dbms_output.put_line(v_string);
		end loop;
	end loop;
end;
/
1 rows affected

dbms_output:
Harry Potter and the Philosopher's Stone
Harry Potter and the Sorcerer's Stone