SQL Server 2017

By using db<>fiddle, you agree to license everything you submit by Creative Commons CC0.

DECLARE @transactions TABLE (Id INT IDENTITY, UserId INT, 
Platforms VARCHAR(MAX), 
TransactionTypeId VARCHAR(MAX));

INSERT INTO @transactions
(
    UserId,
    Platforms,
    TransactionTypeId
)
VALUES
(1, '{"p3":1,"p1":1}', '{"t1":1,"t2":1}'),
(2, '{"p3":2}', '{"t2":1,"t1":1}'),
(1, '{"p2":1}', '{"t1":1}');

WITH plats AS
(
	SELECT UserId,
		   p.[Key] AS pName, SUM(CAST(p.Value AS int)) AS pCount
	FROM @transactions
	CROSS APPLY OPENJSON(Platforms) AS p
	GROUP BY UserId, p.[Key]
),
platGroup AS 
(
	SELECT userId,
	JSON_QUERY( '{' + 
	STRING_AGG( '"' + [pName] + '":' + CAST([pCount] AS varchar(10)), ',' )  
	+ '}' ) Platforms
	FROM plats
	GROUP BY UserId
),
ttypes AS 
(
	SELECT UserId,
		   t.[Key] AS tName, SUM(CAST(t.Value AS Int)) AS tCount
	FROM @transactions
	CROSS APPLY OPENJSON(TransactionTypeId) AS t
	GROUP BY UserId, t.[Key]
),
ttypeGroup AS
(
	SELECT userId,
	JSON_QUERY( '{' + 
	STRING_AGG( '"' + [tName] + '":' + CAST([tCount] AS varchar(10)), ',' )  
	+ '}' ) TransactionTypeId
	FROM ttypes
	GROUP BY UserId
)
SELECT COALESCE(pg.UserId, tg.UserId) AS UserId,
       pg.Platforms,
       tg.TransactionTypeId
FROM platGroup pg
FULL JOIN ttypeGroup tg ON tg.UserId = pg.UserId;

UserId	Platforms	TransactionTypeId
1	{"p1":1,"p2":1,"p3":1}	{"t1":2,"t2":1}
2	{"p3":2}	{"t1":1,"t2":1}