Oracle 18c

By using db<>fiddle, you agree to license everything you submit by Creative Commons CC0.
create TYPE t_params IS
TABLE OF VARCHAR2(32767 CHAR);
CREATE OR REPLACE PROCEDURE modify_cursor (
p_cursor IN OUT SYS_REFCURSOR,
p_array_binary   IN t_params,
p_values         IN t_params
)
IS
  l_c integer;
  l_col_cnt integer;
  l_desc_t dbms_sql.desc_tab3;
  l_varchar2 varchar2(32767 char);
  l_values t_params := new t_params();
  l_result integer;
BEGIN
  l_c := dbms_sql.to_cursor_number(rc => p_cursor);
  dbms_sql.describe_columns3(c => l_c, col_cnt => l_col_cnt, desc_t => l_desc_t);
  -- optionally check l_col_cnt matches sise of t_params arguments?
  l_values.extend(l_col_cnt);

  for i in 1..l_col_cnt loop
    dbms_sql.define_column(c => l_c, position => i, column => l_varchar2, column_size => 32767);
  end loop;

  -- fetch original values
  l_result := dbms_sql.fetch_rows(c => l_c);

  for i in 1..l_col_cnt loop
    -- depending on p_array_binary, set l_values from either fetched data or p_values
    if p_array_binary(i) = '1' then
      l_values(i) := p_values(i);
    else
      -- this forces everything to varchar2, which is OK (ish) for your sample data;
      -- if you have other data types e.g. dates then you will probably want type-specific
      -- handling so you can control the conversions - which affects this, define_column
      -- and the final cursor to retrieve the values. But you have the same issue with p_values.
      dbms_sql.column_value(c => l_c, position => i, value => l_values(i));
    end if;
  end loop;

  -- done with original cursor
  dbms_sql.close_cursor(c => l_c);

  -- re-open cursor using l_values data
  l_varchar2 := 'select ';
  for i in 1..l_col_cnt loop
    if i > 1 then
      l_varchar2 := l_varchar2 || ', ';
    end if;
    if l_desc_t(i).col_type = 2 then
      l_varchar2 := l_varchar2 || l_values(i);
    else
      l_varchar2 := l_varchar2 || '''' || l_values(i) || '''';
    end if;
    l_varchar2 := l_varchar2 || ' as "' || l_desc_t(i).col_name || '"';
  end loop;
  l_varchar2 := l_varchar2 || ' from dual';
  open p_cursor for l_varchar2;
END;
/
declare
  l_rc sys_refcursor;
  l_empid number;
  l_ename varchar2(30);
  l_mgr varchar2(30);
  l_deptNo number;
begin
  open l_rc for
    select 123 as empId, 'king' as ename, 'Porter' as mgr, 200 as deptNo
    from dual;

  modify_cursor(l_rc, t_params('1', '0', '1', '1'), t_params('123', 'king2', 'new manager', '200'));
  
  fetch l_rc into l_empId, l_ename, l_mgr, l_deptNo;

  dbms_output.enable;
  dbms_output.put_line('empId  -> ' || l_empId);
  dbms_output.put_line('ename  -> ' || l_ename);
  dbms_output.put_line('mgr    -> ' || l_mgr);
  dbms_output.put_line('deptNo -> ' || l_deptNo);
end;
/
1 rows affected

dbms_output:
empId  -> 123
ename  -> king
mgr    -> new manager
deptNo -> 200